[koxah]

Для автоматического переподключения попробуйте сделать cmd-файл с таким содержимым:

@echo off

set connection_name="ЗДЕСЬ_ИМЯ_СЕТЕВОГО_ПОДКЛЮЧЕНИЯ"
set host_to_ping=google.com
title Keep-alive Internet Connection Tool

set delay_sec=0
set counter_fail=0
goto check_start

:reconnect
echo Reconnecting... & echo.
rasdial %connection_name% /disconnect >nul || goto reconnect
rasdial %connection_name% >nul
if %errorlevel% equ 692 echo Modem malfunction. Check hardware, then press any key to proceed. & echo. & pause >nul & goto reconnect
if %errorlevel% equ 734 echo Terminated by provider. & echo. & goto delay_reconnect
if %errorlevel% equ 777 echo Provider not responding. & echo. & goto delay_reconnect
if errorlevel 1 echo Error code %errorlevel% - not classified in this program. & echo Check error, then press any key to proceed. & echo. & pause >nul & goto reconnect
ping -n 5 -l 8 -w 5000 %host_to_ping% >nul || (echo No ping response. & echo. & goto delay_reconnect)
set counter_fail=0
goto ping_ok_2

:ping
ping -n 5 -l 8 -w 5000 %host_to_ping% >nul && goto ping_ok_1
echo No ping response. Retry in 30 seconds... & echo.
ping -n 30 127.0.0.1 >nul
ping -n 5 -l 8 -w 5000 %host_to_ping% >nul || (echo No ping response. & echo. & goto reconnect)
goto ping_ok_2

:ping_ok_1
if %delay_sec% lss 600 set /a delay_sec=delay_sec+60
goto ping_ok

:ping_ok_2
set /a delay_sec=60

:ping_ok
set /a delay_min=delay_sec/60
echo Connection OK. Next check in %delay_min% minute(s). & echo.
echo ================================================================================
ping -n %delay_sec% 127.0.0.1 >nul

:check_start
time /time & echo.
echo Checking connection... & echo.
goto ping

:delay_reconnect
set /a counter_fail=counter_fail+1
if %counter_fail% lss 10 goto reconnect
set counter_fail=0
echo Reconnect delayed - waiting 5 minutes... & echo.
echo ================================================================================
ping -n 300 127.0.0.1 >nul
time /time & echo.
goto reconnect

Только в строке "set connection_name="ЗДЕСЬ_ИМЯ_СЕТЕВОГО_ПОДКЛЮЧЕНИЯ"" укажите имя нужного сетевого подключения.